/
DatalogTests.elm
317 lines (312 loc) · 15.7 KB
/
DatalogTests.elm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
module Database.DatalogTests exposing (..)
import Array exposing (Array)
import Database
import Database.Datalog exposing (..)
import Expect
import Test exposing (..)
datalogTests : Test
datalogTests =
describe "Datalog"
[ describe "planRule"
[ test "a simple read turns into a Read -> Project" <|
\_ ->
rule "mortal" [ "who" ]
|> with "greek" [ var "who" ]
|> planRule
|> Expect.equal (Ok (Database.Project [ 0 ] (Database.Read "greek")))
, test "a filtered read turns into a Select" <|
\_ ->
rule "mortal" [ "first name" ]
|> with "greek" [ var "first name", string "of Athens" ]
|> planRule
|> Expect.equal
(Database.Read "greek"
|> Database.Select (Database.Predicate 1 Database.Eq (Database.Constant (Database.String "of Athens")))
|> Database.Project [ 0 ]
|> Ok
)
, test "sharing a variable between two atoms results in a join" <|
\_ ->
rule "reachable" [ "a", "c" ]
|> with "link" [ var "a", var "b" ]
|> with "reachable" [ var "b", var "c" ]
|> planRule
|> Expect.equal
(Database.JoinOn
{ left = Database.Read "reachable"
, right = Database.Read "link"
, fields = [ ( 0, 1 ) ]
}
|> Database.Project [ 2, 1 ]
|> Ok
)
, test "filtering adds a predicate" <|
\_ ->
rule "adult" [ "name" ]
|> with "person" [ var "name", var "age" ]
|> filter (gt "age" (int 20))
|> planRule
|> Expect.equal
(Database.Read "person"
|> Database.Select (Database.Predicate 1 Database.Gt (Database.Constant (Database.Int 20)))
|> Database.Project [ 0 ]
|> Ok
)
, test "filtering using negation adds a predicate" <|
\_ ->
rule "sibling" [ "a", "b" ]
|> with "parent" [ var "parent", var "a" ]
|> with "parent" [ var "parent", var "b" ]
|> filter (not_ (eq "a" (var "b")))
|> planRule
|> Expect.equal
(Database.JoinOn
{ left = Database.Read "parent"
, right = Database.Read "parent"
, fields = [ ( 0, 0 ) ]
}
|> Database.Select (Database.Not (Database.Predicate 3 Database.Eq (Database.Field 1)))
|> Database.Project [ 3, 1 ]
|> Ok
)
, test "filtering using or adds a predicate" <|
\_ ->
rule "teen" [ "name" ]
|> with "person" [ var "name", var "age" ]
|> filter
(or
(gt "age" (int 12))
(lt "age" (int 20))
)
|> planRule
|> Expect.equal
(Database.Read "person"
|> Database.Select
(Database.Or
(Database.Predicate 1 Database.Gt (Database.Constant (Database.Int 12)))
(Database.Predicate 1 Database.Lt (Database.Constant (Database.Int 20)))
)
|> Database.Project [ 0 ]
|> Ok
)
, test "filtering using separate filters adds two filters" <|
\_ ->
rule "oldHockeyTeam" [ "name" ]
|> with "team" [ var "name", var "league", var "age" ]
|> filter (eq "league" (string "NHL"))
|> filter (gt "age" (int 50))
|> planRule
|> Expect.equal
(Database.Read "team"
|> Database.Select (Database.Predicate 2 Database.Gt (Database.Constant (Database.Int 50)))
|> Database.Select (Database.Predicate 1 Database.Eq (Database.Constant (Database.String "NHL")))
|> Database.Project [ 0 ]
|> Ok
)
, test "negation adds an outer join" <|
\_ ->
rule "unreachable" [ "a", "b" ]
|> with "node" [ var "a" ]
|> with "node" [ var "b" ]
|> without "reachable" [ var "a", var "b" ]
|> planRule
|> Expect.equal
(Database.OuterJoinOn
{ keep =
Database.JoinOn
{ fields = []
, left = Database.Read "node"
, right = Database.Read "node"
}
, drop = Database.Read "reachable"
, fields = [ ( 1, 0 ), ( 0, 1 ) ]
}
|> Database.Project [ 1, 0 ]
|> Ok
)
, describe "safety"
[ test "rules are required to have bodies" <|
\_ ->
rule "noBody" [ "a" ]
|> planRule
|> Expect.equal (Err NeedAtLeastOnePositiveAtom)
, test "rules are required to have at least one name" <|
\_ ->
rule "noNames" []
|> with "what" [ var "a" ]
|> planRule
|> Expect.equal (Err NeedAtLeastOneName)
, test "all terms in the head must appear in the body" <|
\_ ->
rule "bad" [ "a", "b" ]
|> with "fine" [ var "a" ]
|> planRule
|> Expect.equal (Err (VariableDoesNotAppearInBody "b"))
, test "you can't have just filters" <|
\_ ->
rule "bad" [ "a" ]
|> filter (eq "a" (string "no"))
|> planRule
|> Expect.equal (Err NeedAtLeastOnePositiveAtom)
, test "you can't filter on an unbound name" <|
\_ ->
rule "bad" [ "a" ]
|> with "fine" [ var "a" ]
|> filter (eq "b" (string "no"))
|> planRule
|> Expect.equal (Err (VariableDoesNotAppearInBody "b"))
, test "every name appearing in a negative atom must also appear in a positive atom" <|
\_ ->
rule "bad" [ "a" ]
|> with "an atom to avoid the must-have-one-positive-atom rule" [ var "b" ]
|> without "here's the problem" [ var "a" ]
|> planRule
|> Expect.equal (Err (VariableMustAppearInPositiveAtom "a"))
]
]
, describe "running a program"
[ test "I can insert data" <|
\_ ->
empty
|> insert "greek" [ string "Socrates" ]
|> Expect.ok
, test "I can't insert variables" <|
\_ ->
empty
|> insert "greek" [ var "who?" ]
|> Expect.equal (Err (CannotInsertVariable "who?"))
, test "I can read the data I wrote back" <|
\_ ->
empty
|> insert "greek" [ string "Socrates" ]
|> Result.andThen
(query
[ rule "query" [ "who" ]
|> with "greek" [ var "who" ]
]
)
|> Result.andThen (readError "query")
|> Expect.equal
(Ok [ Array.fromList [ Database.String "Socrates" ] ])
, test "I can make a recursive query" <|
\_ ->
empty
|> insert "link" [ int 1, int 2 ]
|> Result.andThen (insert "link" [ int 2, int 3 ])
|> Result.andThen (insert "link" [ int 3, int 3 ])
|> Result.andThen (insert "link" [ int 3, int 4 ])
|> Result.andThen
(query
[ rule "reachable" [ "a", "b" ]
|> with "link" [ var "a", var "b" ]
, rule "reachable" [ "a", "c" ]
|> with "link" [ var "a", var "b" ]
|> with "reachable" [ var "b", var "c" ]
]
)
|> Result.andThen (readError "reachable")
|> Expect.equal
(let
link : Int -> Int -> Array Database.Constant
link a b =
Array.fromList [ Database.Int a, Database.Int b ]
in
Ok
[ link 1 2
, link 1 3
, link 1 4
, link 2 3
, link 2 4
, link 3 3
, link 3 4
]
)
, test "I can make a joining query" <|
\_ ->
empty
|> insert "mascot" [ string "Fredbird", string "Cardinals" ]
|> Result.andThen (insert "mascot" [ string "Louie", string "Blues" ])
|> Result.andThen (insert "mascot" [ string "Gritty", string "Flyers" ])
|> Result.andThen (insert "team" [ string "Cardinals", string "St. Louis" ])
|> Result.andThen (insert "team" [ string "Blues", string "St. Louis" ])
|> Result.andThen (insert "team" [ string "Flyers", string "Philadelphia" ])
|> Result.andThen
(query
[ rule "hometown" [ "name", "hometown" ]
|> with "mascot" [ var "name", var "team" ]
|> with "team" [ var "team", var "hometown" ]
]
)
|> Result.andThen (readError "hometown")
|> Expect.equal
(Ok
[ Array.fromList [ Database.String "Fredbird", Database.String "St. Louis" ]
, Array.fromList [ Database.String "Gritty", Database.String "Philadelphia" ]
, Array.fromList [ Database.String "Louie", Database.String "St. Louis" ]
]
)
, test "I can make a query with a negation" <|
\_ ->
empty
|> insert "link" [ int 1, int 2 ]
|> Result.andThen (insert "link" [ int 2, int 3 ])
|> Result.andThen (insert "link" [ int 3, int 3 ])
|> Result.andThen (insert "link" [ int 3, int 4 ])
|> Result.andThen
(query
[ rule "reachable" [ "a", "b" ]
|> with "link" [ var "a", var "b" ]
, rule "reachable" [ "a", "c" ]
|> with "link" [ var "a", var "b" ]
|> with "reachable" [ var "b", var "c" ]
, rule "node" [ "a" ]
|> with "link" [ var "a", var "b" ]
, rule "node" [ "b" ]
|> with "link" [ var "a", var "b" ]
, rule "unreachable" [ "a", "b" ]
|> with "node" [ var "a" ]
|> with "node" [ var "b" ]
|> without "reachable" [ var "a", var "b" ]
]
)
|> Result.andThen (readError "unreachable")
|> Expect.equal
(let
link : Int -> Int -> Array Database.Constant
link a b =
Array.fromList [ Database.Int a, Database.Int b ]
in
Ok
[ link 1 1
, link 2 1
, link 2 2
, link 3 1
, link 3 2
, link 4 1
, link 4 2
, link 4 3
, link 4 4
]
)
, test "I cannot make a query with negative recursion" <|
\_ ->
empty
|> insert "x" [ string "this doesn't matter, we just need it to trigger the rule under test" ]
|> Result.andThen
(query
[ rule "p" [ "x" ]
|> with "x" [ var "x" ]
|> without "q" [ var "x" ]
, rule "q" [ "x" ]
|> with "x" [ var "x" ]
|> without "p" [ var "x" ]
]
)
|> Expect.equal (Err CannotHaveNegationInRecursiveQuery)
]
]
readError : String -> Database.Database -> Result Problem (List (Array Database.Constant))
readError name db =
Database.read name db
|> Result.map Database.rows
|> Result.mapError DatabaseProblem